Detection: Cisco Secure Firewall - High Volume of Intrusion Events Per Host

Description

The following analytic detects internal systems that generate an unusually high volume of intrusion detections within a 30-minute window. It leverages Cisco Secure Firewall Threat Defense logs, specifically focusing on the IntrusionEvent event type, to identify hosts that trigger more than 15 Snort-based signatures during that time. A sudden spike in intrusion alerts originating from a single host may indicate suspicious or malicious activity such as malware execution, command-and-control communication, vulnerability scanning, or lateral movement. In some cases, this behavior may also be caused by misconfigured or outdated software repeatedly tripping detection rules. Systems exhibiting this pattern should be triaged promptly, as repeated Snort rule matches from a single source are often early indicators of compromise, persistence, or active exploitation attempts.

Search

 1`cisco_secure_firewall` EventType=IntrusionEvent
 2
 3| bin _time span=30m
 4
 5| stats count as TotalEvents values(signature_id) as signature_id
 6        values(signature) as signature
 7        values(dest) as dest
 8        values(dest_port) as dest_port
 9        min(_time) as firstTime max(_time) as lastTime 
10        by src_ip class_desc MitreAttackGroups InlineResult InlineResultReason rule transport app
11
12| where TotalEvents >= 15
13
14| `security_content_ctime(firstTime)`
15
16| `security_content_ctime(lastTime)`
17
18| `cisco_secure_firewall___high_volume_of_intrusion_events_per_host_filter`

Data Source

Macros Used

Annotations

Default Configuration

This detection is configured by default in Splunk Enterprise Security to run with the following settings:

Implementation

This search requires Cisco Secure Firewall Threat Defense Logs, which includes the IntrusionEvent EventType. This search uses an input macro named cisco_secure_firewall. We strongly recommend that you specify your environment-specific configurations (index, source, sourcetype, etc.) for Cisco Secure Firewall Threat Defense logs. Replace the macro definition with configurations for your Splunk environment. The search also uses a post-filter macro designed to filter out known false positives. The logs are to be ingested using the Splunk Add-on for Cisco Security Cloud (https://splunkbase.splunk.com/app/7404). The intrusion access policy must also be configured.

Known False Positives

False positives can occur in environments where vulnerability scanners or malware sandboxes are actively generating simulated attacks. Additionally, noisy or overly aggressive Snort rules may produce bursts of alerts from legitimate applications. Review host context before escalating.

Associated Analytic Story

• Cisco Secure Firewall Threat Defense Analytics

Risk Based Analytics (RBA)

Risk Message:

A high number [$TotalEvents$] of Snort intrusion detections for [$signature$] were triggered by [$src_ip$] in a 30-minute time window.

References

• https://www.cisco.com/c/en/us/td/docs/security/firepower/741/api/FQE/secure_firewall_estreamer_fqe_guide_740.pdf

Detection Testing

Replay any dataset to Splunk Enterprise by using our replay.py tool or the UI. Alternatively you can replay a dataset into a Splunk Attack Range

Source: GitHub | Version: 1